델파이로 DirectShow 프로그래밍하기(9) - 어플(5)

지난 8부에서 우리는 비로소 TBaseDShow 클래스를 완성하였습니다. 이제 우리는 DShow용 어플의 기본적인 것을 모두 소화해 낸 것입니다. 이제부터는 노가닥성 코딩이라고 보아도 되겠습니다. TBaseDShow 를 이용하여 필터를 만들고 연결하고 실행하면 되는 것입니다. 이제 TBaseDShow에서 상속받아서 이 나머지 구체화 부분에 해당하는 클래스를 만들겠습니다. 현재 우리는 USB용 카메라를 동작시키기 위한 DShow용 어플을 제작하고 있으므로 이 클래스의 이름을 TCamDShow라고 하겠습니다.

우선 아래와 같은 클래스의 원형을 보시겠습니다. 

type
  TCamDShow = class(TBaseDShow)
  private
    Cam:               IBaseFilter;
    VideoRender:  IBaseFilter;
  protected
  public
    constructor Create(Screen:TPanel);
    destructor Destroy;override;
    function MakeBaseFilter:HRESULT;
    function ReleaseBaseFilter:HRESULT;
    function ConnectBaseFilter:HRESULT;
    procedure Run;
    procedure Stop;
  end;


자, 위의 클래스 원형에서 필터가(IBaseFilter형 타입의 변수) 달랑 두개 뿐이 없는 것을 보실수가 있습니다. 바로 Cam 과 VideoRender 입니다. 이 두개의 필터를 생성하고 연결해 주어야 합니다. (DShow 용 어플 제작에 있어서 필터라는 것은 IBaseFilter 형 타입의 변수를 의미 한다고 보시면 되겠습니다. 그러나 일반적으로 필터라 함은 COM Obejct  객체 자체를 말하는 것이라 생각해야 할 것입니다.). 위에서는 단지 두개뿐이지만 좀 복잡한 어플에서는 훨씬 많은 수의 필터들이 존재하고 있을 것입니다. 지금은 간단한 실습용이기 때문이라고 생각해 주세요.

위에서 두개의 필터와 함께 세개의 함수가 보이실 것입니다. 세개의 함수중 두개는 이름만으로도 이해하기가 쉬우실 것입니다. 즉, MakeBaseFilter는 각각의 필터를 만드는 곳이고,  ConnectBaseFilter는 각각의 필터를 연결하는 장소입니다. 그런데 ReleaseBaseFilter라는 함수는 무엇일까요. 이 함수는 필터들을 해제하기 위한 것입니다.  이것은 그냥 TCamDShow 객체의 소멸자에 해당 로직을 몽땅 몰아 넣어도 상관은 없습니다만, 사용의 편리성을 위해 별도로 준비한 것입니다.

마지막으로 한가지 더 눈여겨 보셔야 할 부분이 있습니다. 그것은 함수의 리턴타입입니다. HResult 라고 되어 있는데요, 이것은  DShow에서 밥먹듯이 사용해야 할 리턴타입니다. 현재 위에서 세개의 함수들이 굳이 HResult 형의 리턴 타입을 사용하지 않아도 상관은 없습니다만, 일부러 이렇게까지 한것은 이러한 관습에 익숙해지면 편리하기 때문입니다.
DShow를 넘어서 COM의 모든 인터페이스의 리턴타입이 바로 HResult입니다. 그렇기 때문에 HResult에 조금이라도 일관성을 유지하면서 익숙해진다면 좋기 때문입니다.  S_OK, S_False 이런 결과 값들을 기본으로 생각하고 있어야 할 것입니다.

자, 이제 생성자와 소멸자를 살펴보겠습니다.

constructor TCamDShow.Create(Screen: TPanel);
begin
  inherited Create;
  MakeBaseFilter;
  ConnectBaseFilter;
  VideoWindow.put_Owner(OAHWND(Screen.Handle));
  VideoWindow.put_WindowStyle(WS_CHILD or WS_CLIPSIBLINGS);
  VideoWindow.put_Width(320);
  VideoWIndow.put_Height(240);
  VideoWindow.put_Top(0);
  VideoWindow.put_Left(0);
end;

 

destructor TCamDShow.Destroy;
begin
  ReleaseBaseFilter;
  inherited Destroy;
end;


소멸자는 간단합니다. 위에서 말씀드린 것처럼 사용된 필터들을 해제하는 로직을 포함해야 하는데요, 이것을 별도의 ReleaseBaseFilter라는 함수에 넣어둔 것일 뿐입니다. 이제 생성자를 한번 보겠습니다. Inherited 아래의 문구에서 처음으로 필터를 생성하고(MakeBaseFilter함수) 그 다음으로 필터를 연결하고(ConnectBaseFilter 함수) 있습니다.

그런데 그 아래에 약간 특이한 코드가 보이는데요. 이것은 전에 말씀드렸듯이 TBaseDShow에 있는 필터그래프의
IVideoWindow 인터페이스를 사용한 것입니다. 이 인터페이스를 사용하여 비디오가 랜더링되는 창을 폼위의 어느곳 이든지 지정할 수가 있다고 설명을 드린적이 있는데요, 바로 이 코드가 그것입니다. TCamDShow 클래스의 생성자 매개변수를 TPanel형 타입으로 받아서 이것을 일종의 랜더링 스크린으로 사용하고 있습니다.

자, 이제 필터를 생성하는 함수를 보겠습니다. 함수는 아래와 같습니다.

function TCamDShow.MakeBaseFilter: HRESULT;
begin
  Result := S_OK; 

  Cam := GetCamFilter;
  FilterGraph.AddFilter(Cam,'Cam Filter'); 
  if Cam = nil then Result := S_FALSE;

 

  CreateFilter(CLSID_VideoRenderer,VideoRender);
  FilterGraph.AddFilter(VideoRender,'VdRenderFilter');
  if VideoRender = nil then Result := S_FALSE;

 

  if Result = S_FALSE then ShowMessage('MakeBaseFilter is Failed');
end;


위에서 보시면 아시겠지만 필터를 생성하자마자 필터그래프에 등록하고(혹은 Add하고) 있습니다. 단지 두개의 필터만이 사용되었기 때문에 현재는 상당히 간단해 보이지만, 사실 이 함수에는 나중에 각각의 필터들 고유의 또다른 인터페이스를 얻어내는 장소가 되기도 할 것입니다. 아무튼 중요한 것은 필터를 생성하고 필터그래프에 등록하였다는 사실입니다.  

위의 함수에서 조금 더 부언 설명을 드려야 하겠습니다. 카메라를 생성시킬때 사용한 GetCamFilter 라는 함수는 전장에서 TBaseDShow 클래스에서 소개한 적이 있었습니다. 그런데 사실 일반적으로 이렇게 Fixed하게 만들어 놓지는  않습니다. 보통 카테고리에서 특정한 장치(혹은 광의의 필터)를 얻어오기 위함 범용 함수를 만들어 놓고 사용하는데요
여기서는 이해의 편리를 위해 직설적으로 GetCamFilter라는 이름으로 간단하게 구성하게 된 것입니다. 

CreateFilter라는 함수는 기억하실 것입니다. 이것은 필터그래프를 생성하는 함수와 거의 동일하기 때문에 COM Object를 생성하는 범용함수를 만들어 놓고 사용해도 된다는 식의 설명을 드린적이 있을 것입니다. 자... 여기까지 이해가 어느정도 되셨을 것이라고 생각하겠습니다. 이제 두개의 필터를 연결하는 함수를 보시겠습니다.

function TCamDShow.ConnectBaseFilter: HRESULT;
var
  InPin : IPin;
  OutPin : IPin;
  hr : HRESULT;
begin
  Result := S_OK;
 

  FindPinOnFilter(Cam,PINDIR_OUTPUT,OutPin);
  FindPinOnFilter(VideoRender,PINDIR_InPUT,InPin);
  hr := FilterGraph.Connect(OutPin,InPin);
  if hr <> S_OK then Result := S_FALSE;
 

  OutPin := NIL;
  InPin := NIL;
 

  if Result = S_FALSE then ShowMessage('ConnectBaseFilter is Failed');
end;

위의 함수도 내용은 간단합니다. 두개의 필터 각각의 InPin과  OutPin 인터페이스를 얻어서 필터그래프로 하여금 두개의 핀을 연결시키게 하고 있습니다. 이때 FindPinOnFilter 함수는 여러분이 전장에서 TBaseDShow에 기술한 바로 그 함수입니다. FindPinOnFilter 매개변수로는 필터의 IBaseFilter 인터페이스형 변수와 핀의 방향, 그리고 마지막으로 받아낼 핀의 인터페이스형 변수가 되겠습니다. 

한가지 의문이 들수도 있을 것입니다. 위에서는 단지 두개의 필터를 연결시켰지만, 수많은 필터들을 연결시킬때에는 어떻게 할까하는 점입니다. 위의 코딩을 계속 반복해 나가면 얼마든지 필터를 연결시킬 수가 있습니다. 즉 순서대로  출력에서부터 최종 랜더링까지,  앞 필터의 출력핀을 얻고 뒷필터의 입력핀을 얻어서 연결하고, 다시 뒷필터의 출력핀을 얻고, 그 뒤뒤필터의 입력핀을 얻어서 연결하고... 이렇게 반복될 것입니다. 이 부분에 대해서는 뒤에서 동영상 파일의 랜더링 부분에 가서 구경하실 수가 있으실 것입니다.

이제 마지막으로 필터들을 소멸시키는 함수를 보시겠습니다.


function TCamDShow.ReleaseBaseFilter: HRESULT;
begin
  if Assigned(MediaControl) then MediaControl.Stop;
 

  FilterGraph.RemoveFilter(Cam);
  FilterGraph.RemoveFilter(VideoRender);
 

  While Assigned(Cam)             do Cam := nil;
  While Assigned(VideoRender)     do VideoRender := nil;
 

  Result := S_OK;
end;


위에서 필터들을 해제하기 바로 전에 필터그래프가 자신에게 등록되었던 필터들을 ReMove시키고 있는 것을 보실 수가 있습니다. 이것을 반드시 해두시라고 말씀은 못드리겠지만 해두시는 게 좋습니다.
자, 필터를 해제하는데 While문을 사용한 이유에 대해서는 전장에서 설명을 드렸으니, 여기서 다시 설명하지는 않겠습니다. 

마지막으로 우리는 두개의 함수, 즉 Run 과 Stop 함수를 보셔야 겠는데요, 이것은 아주 간단한 것입니다. 아래를 보시겠습니다. 
procedure TCamDShow.Run;
begin
  if Assigned(MediaControl) then MediaControl.Run;
end;
 

procedure TCamDShow.Stop;
begin
  if Assigned(MediaControl) then MediaControl.Stop;
end;

위에서 보시면 아시겠지만 MediaControl 인터페이스의 Run과 Stop 메소드를 사용하고 있습니다. MediaControl 는 필터그래프에서 얻은 인터페이스라고 설명을 드렸을 것입니다. 이제 모든것이 정리되었습니다. 완전한 풀 소스를 아래와 같이 보시겠습니다. 

unit cCamDShow;

interface
uses
  Windows, Dialogs, SysUtils, Classes, Registry, DirectShow9, ActiveX, ExtCtrls, DsUtil, cBaseDShow;

 

type
  TCamDShow = class(TBaseDShow)
  private
    Cam:          IBaseFilter;
    VideoRender:  IBaseFilter;
  protected
  public
    constructor Create(Screen:TPanel);
    destructor Destroy;override;
    function MakeBaseFilter:HRESULT;
    function ReleaseBaseFilter:HRESULT;
    function ConnectBaseFilter:HRESULT;
    procedure Run;
    procedure Stop;
  end;

 

implementation
 
 

{ TCamDShow }

 

constructor TCamDShow.Create(Screen: TPanel);
begin
  inherited Create;
  MakeBaseFilter;
  ConnectBaseFilter;
  VideoWindow.put_Owner(OAHWND(Screen.Handle));
  VideoWindow.put_WindowStyle(WS_CHILD or WS_CLIPSIBLINGS);
  VideoWindow.put_Width(320);
  VideoWIndow.put_Height(240);
  VideoWindow.put_Top(0);
  VideoWindow.put_Left(0);
end;

 

destructor TCamDShow.Destroy;
begin
  ReleaseBaseFilter;
  inherited Destroy;
end;

 

function TCamDShow.MakeBaseFilter: HRESULT;
begin
  Result := S_OK;

  Cam := GetCamFilter;   //카메라를 얻고...
  FilterGraph.AddFilter(Cam,'Cam Filter');  //카메라를 등록한다.
  if Cam = nil then Result := S_FALSE;

  CreateFilter(CLSID_VideoRenderer,VideoRender);  //비디오 랜더러를 얻고...
  FilterGraph.AddFilter(VideoRender,'VdRenderFilter'); //비디오 랜더러를 등록한다.
  if VideoRender = nil then Result := S_FALSE;

  if Result = S_FALSE then ShowMessage('MakeBaseFilter is Failed');
end;

 

function TCamDShow.ConnectBaseFilter: HRESULT;
var
  InPin : IPin;
  OutPin : IPin;
  hr : HRESULT;
begin
  Result := S_OK;

  FindPinOnFilter(Cam,PINDIR_OUTPUT,OutPin);     //Cam에서 첫번째 출력핀을 얻어낸다.
  FindPinOnFilter(VideoRender,PINDIR_InPUT,InPin); //랜더러에서 첫번째 입력핀을 얻어낸다.
  hr := FilterGraph.Connect(OutPin,InPin);       //필터그래프가 두개의 핀을 연결한다.
  if hr <> S_OK then Result := S_FALSE;
  hr := S_OK;

  OutPin := NIL;
  InPin := NIL;

  if Result = S_FALSE then ShowMessage('ConnectBaseFilter is Failed');
end;

 

function TCamDShow.ReleaseBaseFilter: HRESULT;
begin
  if Assigned(MediaControl) then MediaControl.Stop;

  FilterGraph.RemoveFilter(Cam);
  FilterGraph.RemoveFilter(VideoRender);

  While Assigned(Cam)             do Cam := nil;
  While Assigned(VideoRender)     do VideoRender := nil;

  Result := S_OK;
end;

 

procedure TCamDShow.Run;
begin
  if Assigned(MediaControl) then MediaControl.Run;
end;

 

procedure TCamDShow.Stop;
begin
  if Assigned(MediaControl) then MediaControl.Stop;
end;

end.  

자, TCamDShow 클래스를 사용하는 방법은 너무도 간단합니다. 델파이에서 빈프로젝트를 하나 시작합니다.
메인폼위에 Panel 하나와 버튼 두개를 올려놓습니다. 그리고 버튼의 클릭 이벤트에서 각각 다음과 같이 코딩해 놓습니다.

unit uMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, cCamDShow, StdCtrls, ExtCtrls;
 

type
  TfrmMain = class(TForm)
    Panel1: TPanel;
    Run_Button: TButton;
    Stop_Button: TButton;
    procedure Run_ButtonClick(Sender: TObject);
    procedure Stop_ButtonClick(Sender: TObject);
  private
  public
    CamDShow :TCamDShow;
  end;
 

var
  frmMain: TfrmMain;

implementation
                           
{$R *.dfm}

//Run 버튼을 클릭하였을 때...

procedure TfrmMain.Run_ButtonClick(Sender: TObject);
begin
  if not Assigned(CamDShow) then
  begin
    CamDShow := TCamDShow.Create(Panel1);
  end;

  CamDShow.Run;
end;


//Stop 버튼을 클릭하였을 때...

procedure TfrmMain.Stop_ButtonClick(Sender: TObject);
begin
  CamDShow.Stop;
end;

end.


지금까지의 프로젝트를 첨부파일로 올려놓았습니다. (델파이7) 

 

출처 : 델마당  dong님의 글(dongsoft)